devtools/kube/hackdoc.libsonnet

local mirko = import "../../kube/mirko.libsonnet";
local kube = import "../../kube/kube.libsonnet";

{
    cfg:: {
        image: "registry.k0.hswaw.net/q3k/hackdoc:315532800-a415ced850425a195f96b331f57cd78f15e622d9",
        publicFQDN: error "public FQDN must be set",
    },

    component(cfg ,env):: mirko.Component(env, "hackdoc") {
        local hackdoc = self,
        cfg+: {
            image: cfg.image,
            container: hackdoc.GoContainer("main", "/devtools/hackdoc") {
                command+: [
                    "-depotview=depotview.devtools-prod.svc.cluster.local:4200",
                    "-hackdoc_url=https://%s" % [cfg.publicFQDN],
                    "-pub_listen=0.0.0.0:8080",
                ],
            },
            ports+: {
                publicHTTP: {
                    public: {
                        port: 8080,
                        dns: cfg.publicFQDN,
                    },
                },
            },
        },
    }
}