hswaw/machines/tv/signage.nix

{ love, curl, fetchFromGitHub, fetchgit, stdenv, lib, ... }:
let
  love12 = (love.overrideAttrs (oa: {
    version = "12.0-dev";
    src = fetchFromGitHub {
      owner = "love2d";
      repo = "love";
      rev = "d586d1847446f5212d5f7e9efb94e50fcfba7d77";
      sha256 = "sha256-gTpVtyqXV6/GsezuCpooaY+x5tPfOF9p1b83v4kKR4E=";
    };
    makeFlags = [
      "CPPFLAGS=-DHTTPS_BACKEND_CURL"
    ];
    buildInputs = oa.buildInputs ++ [ curl ];
    NIX_LDFLAGS = "-lcurl";
    enableParallelBuilding = true;
  }));

  signage = stdenv.mkDerivation {
    name = "signage";
    src = fetchgit {
      url = "https://code.hackerspace.pl/q3k/love2d-signage";
      rev = "6c14716222e28b004861b3926560bf21d519fb00";
      sha256 = "sha256-dfZ6Q320+ukMt9Q2igcARBM72LRbW5ltEvxrngSW8fQ=";
    };

    installPhase = ''
      mkdir -p $out/share/signage
      cp -rv $src/* $out/share/signage/

      mkdir -p $out/bin/
      cat <<EOF >$out/bin/signage
      #!/usr/bin/env bash
      ${love12}/bin/love $out/share/signage
      EOF
      chmod +x $out/bin/signage
    '';
  };

in signage