local mirko = import "../../kube/mirko.libsonnet";
local kube = import "../../kube/kube.libsonnet";

{
    cfg:: {
        secret: {
            telegram_token: error "telegram_token must be set",
        },
        image: {
            teleimg: "registry.k0.hswaw.net/q3k/teleimg:1578259776-a07688fe74efe1e190d58092a9f50d4275a15e3d",
        },
        webFQDN: error "webFQDN must be set!",
    },

    teleimg(cfg, env):: mirko.Component(env, "teleimg") {
        local teleimg = self,
        cfg+: {
            image: cfg.image.teleimg,
            container: teleimg.GoContainer("main", "/teleimg/teleimg") {
                env_: {
                    TELEGRAM_TOKEN: kube.SecretKeyRef(teleimg.secret, "telegram_token"),
                },
                command+: [
                    "-public_listen", "0.0.0.0:5000",
                    "-telegram_token", "$(TELEGRAM_TOKEN)",
                ],
            },
            ports+: {
                publicHTTP: {
                    public: {
                        port: 5000,
                        dns: cfg.webFQDN,
                    },
                },
            },
        },

        secret: kube.Secret("teleimg") {
            metadata+: teleimg.metadata,
            data: cfg.secret,
        },
    },
}